MikroTik два провайдера.

Разберем тему работы сети с двумя провайдерами на Микротик , настройки маршрутизации и распределение трафика по подсетям.

Условия:
На MikroTik приходит два канала от одного провайдера, с разными статическими IP.
Шлюз у обоих ip-адресов одинаковый 1.1.1.254.

Необходимо разделить 4 локальные подсети таким образом, что бы две (192.168.1.0/24, 192.168.2.0/24) ходили наружу по WAN1 (1.1.1.1),а другие две (192.168.3.0/24, 192.168.4.0/24) по WAN2 (1.1.1.2).

WAN1 (1.1.1.1)
WAN2 (1.1.1.2)

1.Назначена адресация интерфейсов:

/ip address
add address=1.1.1.1/24 network=1.1.1.0 interface=WAN1
add address=1.1.1.2/24 network=1.1.1.0 interface=WAN2
add address=192.168.1.1/24 network=192.168.1.0 interface=Local1
add address=192.168.2.1/24 network=192.168.2.0 interface=Local2
add address=192.168.3.1/24 network=192.168.3.0 interface=Local3
add address=192.168.4.1/24 network=192.168.4.0 interface=Local4

2.Создаем адрес листы, по которым раскидываем подсети, согласно которым будут распределяться внешние каналы:

/ip firewall address-list
add address=192.168.1.0/24 list=office_address_list
add address=192.168.2.0/24 list=office_address_list
add address=192.168.3.0/24 list=servers_address_list
add address=192.168.4.0/24 list=servers_address_list

3.Маркируем каналы, указав каждому из них адрес лист:

/ip firewall mangle
add action=mark-routing chain=prerouting new-routing-mark=WAN1_1.1.1.1 src-address-list=office_address_list
add action=mark-routing chain=prerouting new-routing-mark=WAN2_1.1.1.2 src-address-list=servers_address_list

4.Настраиваем правила NAT выхода в интернет:

/ip firewall nat
add action=src-nat chain=srcnat out-interface=WAN1 src-address=192.168.1.0/24 to-addresses=1.1.1.1
add action=src-nat chain=srcnat out-interface=WAN1 src-address=192.168.2.0/24 to-addresses=1.1.1.1
add action=src-nat chain=srcnat out-interface=WAN2 src-address=192.168.3.0/24 to-addresses=1.1.1.2
add action=src-nat chain=srcnat out-interface=WAN2 src-address=192.168.4.0/24 to-addresses=1.1.1.2

5.Прописываем статически маршруты, обратите внимание, так как оба внешних ip-адреса провайдера используют один и тот же шлюз, мы добавляем через % имя интерфейса, с которого они выходят:

/ip route
add check-gateway=ping distance=1 gateway=1.1.1.254%WAN1 pref-src=1.1.1.1 routing-mark=WAN1_1.1.1.1
add check-gateway=ping distance=1 gateway=1.1.1.254%WAN2 pref-src=1.1.1.2 routing-mark=WAN2_1.1.1.2
add check-gateway=ping disabled=yes distance=1 gateway=1.1.1.254

6.Добавляем правила:

/ip route rule
add dst-address=192.168.1.0/24 action=lookup table=main
add dst-address=192.168.2.0/24 action=lookup table=main
add dst-address=192.168.3.0/24 action=lookup table=main
add dst-address=192.168.4.0/24 action=lookup table=main
add dst-address=1.1.1.0/24 action=lookup table=main

7.Настраиваем forwarding:

/ip firewall filter
add action=accept chain=forward src-address=192.168.1.0/24
add action=accept chain=forward dst-address=192.168.1.0/24
add action=accept chain=forward src-address=192.168.2.0/24
add action=accept chain=forward dst-address=192.168.2.0/24
add action=accept chain=forward src-address=192.168.3.0/24
add action=accept chain=forward dst-address=192.168.3.0/24
add action=accept chain=forward src-address=192.168.4.0/24
add action=accept chain=forward dst-address=192.168.4.0/24

Таким образом мы выполнили задачу: одновременная работа двух провайдеров mikrotik c разделение локальных сетей.